明确ANSYS中的阻尼，声吸收，阻抗的含义：

阻尼是指动力学问题相关的能量损失，可以在瞬态或谐波声学中包括。声的吸收和阻抗指压力自由度相关的损失。ANSYS中的阻抗用来标识声表面可以吸收能量的开关，MU指能量在指定声表面被吸收的数量。这个用途对ANSYS是特殊的，意义比广义声学中更为严格。

　　通常的一个误解是约束的边界是吸收边界。实际上这种边界反射压力脉冲并将其反号。各种边界条件总结如下：

　MU值 　　 DOF（自由度约束) 结果边界条件

　u=0 　　　未约束 　　　　　  无压力反号

　Mu=1 　　 未约束 　　　　　 吸收边界（仿佛另一侧有相同材料）

　Mu=∞ 　　未约束 　　　　　　压力反向的反射边界

　Mu=any 　 约束 　　　　　　　压力反向的反射边界

　　Mu=0 模拟刚性壁条件：无吸收，100%反射声能。Mu<1表示（至少是典型如此）声波从低密度流体进入高密度流体。例如声波在空气中传播碰到空气/水界面就像遇到刚性墙壁，因此Mu会很小，为0.05。在谱的另一端，MU=∞相应于压力释放（P=0）边界。声在水中传播遇到空气/水界面就如同是p=0边界。这样大的MU值可以用于模拟声在水中传播的空气/水边界。如果要模拟声从高密度媒质到低密度媒质，设定的MU值应大于1。

　　下面例子示意了阻尼和声吸收的使用。这个问题是声学管，类似于管弦乐和弦，施加到一端的压力向另一端传递在尽头反射。问题包括压力波的几次反复，表明在管封闭端的吸收。包括了不同的阻尼值（对阻尼矩阵）和MU（吸声端）。阻抗值对全反射边界为0，有吸收的为1。

/show,acous,f33

*dim,dval,,5

*dim,mval,,5

dval(1)=.01 $ mval(1)=0

dval(2)=.05 $ mval(2)=.25

dval(3)=.1 $ mval(3)=.50

dval(4)=.2 $ mval(4)=.75

dval(5)=.3 $ mval(5)=1

*do,ii,1,5 ! loop on damping

*do,jj,1,5 ! loop on absorption

parsav,all ! save parameters for /clear

/clear, ! start new problem

parres

/TITLE, TRAVELING ACOUSTIC WAVE, DAMP = %dval(ii)%, MU = %mval(jj)%

/prep7

et,1,29,,1 ! 2d acoustic fluid

n,1 ! define nodes

n,101,100 ! make tube 100 long

fill

n,201,,1

n,301,100,1

fill

e,1,2,202,201 ! define elements

*repeat,100,1,1,1,1

dens,1,9.633e-5

sonc,1,10000 ! define sonic for 100 hz freq

damp,1,dval(ii) ! transient problem, need some damping

mu,1,mval(jj) ! specify sound absorption at end

FINISH

/solu

antype,tran

outres,all,all

nsel,s,,,101,301,200 ! select nodes at end

sf,all,impd,1 ! enable sound absorption

nsel,all

!

! apply pressure at x = 0

time,.0005

d,1,pres,1,,201,200 ! apply pressure at start

deltim,.0001 ! delta time for solutions

solve

d,1,pres,0,,201,200

time,.001

solve

time,.07 ! at least two traverses

solve

finish

/post26

nsol,2,21,pres,,.2*LENG ! store pressure at some locations

nsol,3,41,pres,,.4*LENG

nsol,4,61,pres,,.6*LENG

nsol,5,81,pres,,.8*LENG

nsol,6,101,pres,,END

plvar,2,3,4,5,6 ! plot all

finish

*enddo

*enddo